EXCEL-Aufgaben zum Übergangsbereich (früher Gleitzone)

Beitragsberechnung im Übergangsbereich (früher Gleitzone) für 2025

Erstellen Sie folgende Tabelle. Die grauen Zellen enthalten Formeln. Die gelben Zellen sind Eingabefelder.

Berechnung der SV-Beiträge in der Gleitzone für 2025

In B5 und B6 sollen die Grenzen für den Übergangsbereich stehen.
§ 163 Abs. 7 SGB VI: Bei Beschäftigten, die gegen ein monatliches Arbeitsentgelt bis zum oberen Grenzbetrag des Übergangsbereichs (§ 20 Absatz 2 des Vierten Buches) mehr als geringfügig beschäftigt sind, berechnet sich die beitragspflichtige Einnahme nach § 20 Absatz 2a Satz 1 des Vierten Buches.

Die Geringfügigkeitsgrenze ist im § 8 Abs. 1a SGB IV definiert. Sie wird berechnet, indem der Mindestlohn mit 130 vervielfacht, durch drei geteilt und auf volle Euro aufgerundet wird.
Die Geringfügigkeitsgrenze steht in B5. Zur Umsetzung brauchen Sie die Funktion AUFRUNDEN. Sie nehmen Bezug auf B4 mit dem Mindestlohn.
=AUFRUNDEN(B4*130/3;0)
Es ergeben sich 556 €
Kleine Überprüfung:
Bei Eintragung von 12 € in B4 (Mindestlohn vom 01.10.2022 bis 31.12.2023) müssen sich 520 € in B5 ergeben.
Bei Eintragung von 12,41 € in B4 (Mindestlohn vom 01.01.2024 bis 31.12.2024) müssen sich 538 € in B5 ergeben.

Der obere Grenzbetrag des Übergangsbereichs soll in B6 eingegeben werden.

Die Werte in B10 bis B14 sind Eingabewerte (Beitragssätze zur Sozialversicherung 2025).
Übersicht der Sozialversicherungsbeiträge 2025
In B15 errechnen Sie die Summe von B10 bis B14 (Gesamtsozialversicherungsbeitragssatz).
In B16 errechnen Sie den Faktor F. Es gilt § 20 Abs. 2a SGB IV: 28% geteilt durch den Gesamtsozialversicherungsbeitragssatz. Er wird auf die vierte Dezimalstelle gerundet.
Die 28% ergeben sich aus: 15% Pauschalbeitrag zur Rentenversicherung + 13% Pauschalbeitrag zur Krankenversicherung bei eineer geringfügig entlohnten Beschäftigung.
Zur Umsetzung brauchen Sie die Funktion RUNDEN. Sie nehmen Bezug auf B15 mit dem Gesamtsozialversicherungsbeitragssatz.
=RUNDEN(28%/B15;4)
Es ergeben sich 0,6683

Die Werte in B18 und B20 bis B22 sind Eingabewerte.
In B20, B21 und B22 werden mit der Datenüberprüfung auf Zellen mögliche Zelleinträge festgelegt. Die Optionen für die Datenüberprüfung befinden sich auf der Registerkarte Daten in der Gruppe Datentools.
In B21 und B22 ist nur ja oder nein zulässig. Wählen Sie im Feld Zulassen die Option Liste aus. Geben Sie in das Feld Quelle die zwei Listenwerte mit Semikolon als Trennzeichen ein.

In B20 sollen nur Dezimalzahlen zwischen 556,01 und 2.000 zulässig sein. Wählen Sie im Feld Zulassen die Option Dezimal aus. Nehmen Sie Bezug auf B5 und B6.
Abbildung für Zelle B20:

Die Besonderheiten bei schwankendem Verdienst werden hier nicht behandelt. Trotz Schwankungen (mehr oder weniger Stunden im Monat oder Zahlung von Urlaubs- bzw. Weihnachtsgeld) kann der Verdienst im gesamten Jahr innerhalb des Übergangsbereichs liegen. Entscheidend ist der Durchschnitt. Für die Berechnung der SV-Beiträge sind dann drei Fälle möglich:

Entgelt liegt innerhalb des Übergangsbereich (Gleitzone)
Normale Beitragsberechnung im Übergangsbereich
Entgelt liegt unterhalb des Übergangsbereich (Gleitzone)
In solchen Fällen errechnet sich die beitragspflichtige Einnahme durch Multiplikation des Faktors F mit dem erzielten Arbeitsentgelt. Der Arbeitgeber trägt den gesamten Beitrag mit Ausnahme des vom Arbeitnehmer zu tragenden Beitragszuschlags zur Pflegeversicherung für Kinderlose.
Wird hier nicht behandelt.
Entgelt liegt oberhalb des Übergangsbereich (Gleitzone)
Die Beitragsberechnung erfolgt nach den allgemeinen Regelungen zur Beitragsberechnung in der Sozialversicherung.
Wird hier nicht behandelt.

Diese Aufgabe behandelt nur den ersten Fall. Weitere Informationen zum Übergangsbereich (früher Gleitzone).

Die Besonderheiten für Sachsen und den Beitragszuschlag zur Pflegeversicherung für Kinderlose soll unser Schema behandeln.

Als weitere Besonderheit kommt ab 1. Juli 2023 die Kinderzahl dazu.
Eltern mit mehr als einem Kind werden entlastet. Der Beitrag wird ab dem zweiten Kind um 0,25 Prozent pro Kind gesenkt. Die Entlastung wird auf maximal 1,0 Prozent begrenzt. Ab dem fünften Kind bleibt es bei einer Entlastung in Höhe eines Abschlags von insgesamt bis zu 1,0 Prozent. Der Abschlag gilt nur bis zum Ablauf des Monats, in dem das jeweilige Kind das 25. Lebensjahr vollendet hat.
Es ändert sich beim Beitrag zur Pflegeversicherung nur der Gesamtbeitrag und der Arbeitnehmer-Anteil. Der Arbeitgeber-Anteil bleibt gleich.
Diese Besonderheit wird in unserem Schema nicht behandelt.
Ich möchte die Aufgabe nicht verkomplizieren.
Bei entsprechendem Interesse werde ich die Aufgabe entsprechend ergänzen und ausbauen.

In B23 ist der Zusatzbeitragssatz der Krankenkasse des Arbeitnehmers einzutragen.
Wichtig: Für die Berechnung des Faktor F ist bei der Krankenversicherung der um den durchschnittlichen Zusatzbeitragssatz erhöhte allgemeine Beitragssatz anzusetzen.
Bei der Beitragsberechnung im Übergangsbereich (Gleitzone) wird dann mit dem krankenkassenindividuellen Zusatzbeitrag des Arbeitnehmer gerechnet.

In B29 ist die fiktive beitragspflichtige Einnahme auszurechnen (§ 20 Absatz 2a Satz 1 SGB IV).
Die Formel lautet: F * Geringfügigkeitsgrenze + ([2000/(2000-Geringfügigkeitsgrenze)] - [Geringfügigkeitsgrenze/(2000-Geringfügigkeitsgrenze)] * F) * (Arbeitsentgelt - Geringfügigkeitsgrenze)
Wenn wir die Geringfügigkeitsgrenze für 2025 eingeben: F * 556 + ([2000/(2000-556)] - [556/(2000-556)] * F) * (Arbeitsentgelt - 556)
Da die Formel auch im nächsten Jahr funktionieren soll, rechnen wir die Zwischenergebnisse nicht aus. Unsere Formel nimmt Bezug auf B5, B6, B16 und B20. Das Ergebnis ist auf zwei Stellen nach dem Komma zu runden.
=RUNDEN(B16*B5+((B6/(B6-B5))-(B5/(B6-B5))*B16)*(B20-B5);2)
Auf die richtige Klammersetzung ist zu achten.

In B34 ist die beitragspflichtigen Einnahme des vom Arbeitnehmer zu tragenden Anteils am Sozialversicherungsbeitrag auszurechnen (§ 20 Absatz 2a Satz 6 SGB IV).
Die Formel lautet: (2000/(2000-Geringfügigkeitsgrenze)) * (Arbeitsentgelt - Geringfügigkeitsgrenze)
Wenn wir die Geringfügigkeitsgrenze für 2025 eingeben: (2000/(2000-556)) * (Arbeitsentgelt - 556)
Da die Formel auch im nächsten Jahr funktionieren soll, rechnen wir die Zwischenergebnisse nicht aus. Unsere Formel nimmt Bezug auf B5, B6 und B20. Das Ergebnis ist auf zwei Stellen nach dem Komma zu runden.
=RUNDEN((B6/(B6-B5))*(B20-B5);2)
Auf die richtige Klammersetzung ist zu achten.

Wenn Sie die zwei Formeln überprüfen wollen, finden Sie auf der Seite Beitragsberechnung im Übergangsbereich (Gleitzone) für 2025 Beispielzahlen für Arbeitsentgelt, fiktive beitragspflichtige Einnahme und beitragspflichtige Einnahme Arbeitnehmerbeitrag
Geben Sie in B20 andere Werte für das Arbeitsentgelt ein. Stellen Sie dann aber wieder 800 ein.

Erstellen Sie die Tabelle (Zeilen 37 bis 46) entsprechend der obigen Abbildung. Die grauen Zellen enthalten Formeln.
Übernehmen Sie in den Zellen B39 und C39 die Werte aus den Zellen B29 und B34 (=B29 bzw. =B34).
In den Zellen B40 bis C44 brauchen Sie die Funktion RUNDEN.
In D40 (Arbeitgeber-Anteil) ziehen Sie von B40 (Gesamtbeitrag) den Wert in C40 (Arbeitnehmer-Anteil) ab. Die Formel kopieren Sie bis D44.
In der Zeile 45 bilden Sie die Summen aus Zeile 40 bis 44.
Die verbundene Zelle C46 dient nur der Kontrolle. Hier werden die Werte aus C45 und D45 addiert. Es muss sich der gleiche Betrag wie in B45 ergeben.

Spalte B in der Tabelle:
Der Gesamtbeitrag für jeden Versicherungszweig wird durch die Anwendung des halben Beitragssatzes auf die beitragspflichtige Einnahme und anschließender Verdoppelung des gerundeten Ergebnisses ermittelt (§ 2 Abs. 2 Satz 1 BVV).
In der Krankenversicherung ergeben Beitragssatz plus individueller Zusatzbeitragssatz den Gesamtbeitrag zur Krankenversicherung. Dieser wird halbiert und mit der beitragspflichtige Einnahme multipliziert. Rundung des Ergebnis. Dieser Betrag wird verdoppelt.
Besonderheit Beitragszuschlag für Kinderlose B42: Vom Beschäftigten allein zu tragende Beitragsanteile werden durch Anwendung des maßgebenden Beitragssatzes oder Beitragszuschlags auf die beitragspflichtige Einnahme berechnet und auf zwei Dezimalstellen gerundet. Sie brauchen die WENN-Funktion. Wenn die Elterneigenschaft auf ja steht, ist kein Beitragszuschlag fällig.
B40: =RUNDEN(($B$13+$B$23)/2*B39;2)*2
B41: =RUNDEN($B$12/2*B39;2)*2
B42: =WENN(B22="ja";0;RUNDEN(B18*B39;2))
B43: =RUNDEN($B$10/2*B39;2)*2
B44: =RUNDEN($B$11/2*B39;2)*2

Wenn Sie die Zellbezüge auf die Beitragssätze absolut gesetzt haben (Dollarzeichen) können Sie die Formeln aus B40, B43 und B44 nach rechts in Spalte C kopieren.
Es ändert sich der Zellbezug von B39 auf C39.
Da hier nur der Arbeitgeber-Anteil ermittelt wird, ist die Multiplikation mit 2 zu entfernen.
Besonderheit Pflegeversicherung C41 (Arbeitsort in Sachsen): In Sachsen gibt es eine andere Verteilung auf Arbeitnehmer und Arbeitgeber. Der Arbeitnehmer-Anteil ist 0,5% höher und der Arbeitgeber-Anteil 0,5% niedriger. Sie brauchen die WENN-Funktion. Wenn Sachsen auf ja steht, werden zum halben Beitragssatz 0,5% addiert.
Besonderheit Beitragszuschlag für Kinderlose C42: Der Beitragszuschlag wurde beim Gesamtbeitrag ermittelt und wird nur in die Spalte Arbeitnehmer-Anteil übernommen. Wenn kein Beitragszuschlag in B42 steht, wird in C42 auch 0 ausgewiesen. Damit ist auch sichergestellt, dass beim Arbeitgeber-Anteil immer 0 steht. Den Beitragszuschlag zahlt nur der Arbeitnehmer.
C40: =RUNDEN(($B$13+$B$23)/2*C39;2)
C41: =WENN(B21="ja";RUNDEN((B12/2+0,5%)*C39;2);RUNDEN($B$12/2*C39;2))
C42: =B42
C43: =RUNDEN($B$10/2*C39;2)
C44: =RUNDEN($B$11/2*C39;2)

Besonderheit Land Sachsen

Wenn in B21 ein "ja" steht, muss folgendes passieren (Elterneigenschaft in B22 lassen wir auf ja):

Der Arbeitgeberanteil ist in Sachsen niedriger. Das erste Prozent zahlt in Sachsen der Arbeitnehmer allein (ausführliche Informationen zur Beitragsberechnung in Sachsen).
Hintergrund: Der Beitragssatz wurde am 01.01.1995 auf 1% der beitragspflichtigen Einnahmen festgesetzt. Zum Ausgleich der Arbeitgeberbeiträge sollten die Bundesländer einen gesetzlichen landesweiten Feiertag, der stets auf einen Werktag fällt, aufheben. In Bundesländern die den Feiertag gestrichen haben (alle außer Sachsen) wurde der Beitrag von Arbeitgeber und Arbeitnehmer je zur Hälfte (je 0,5%) getragen. In Sachsen hatten die Arbeitnehmer den Beitrag allein zu tragen (Arbeitnehmer 1% und Arbeitgeber 0%). Die späteren Beitragserhöhungen wurden ohne weitere Bedingungen je zur Hälfte auf Arbeitgeber und Arbeitnehmer aufgeteilt.
Damit ist die Beitragsverteilung in Sachsen 2025 so: Arbeitgeber 1,30% und Arbeitnehmer 2,30%.

Der Gesamtbeitrag zur Pflegeversicherung ist immer noch 23,28 €.
Der Arbeitnehmer-Anteil ist aber 7,77 € (2,30% Arbeitnehmer-Anteil * 337,95 €).
Der Arbeitgeber-Anteil wäre dann aber 15,51 € (23,28 - 7,77).

Besonderheit Beitragszuschlag zur Pflegeversicherung für Kinderlose (keine Elterneigenschaft)

Wenn in B22 ein "nein" steht, muss folgendes passieren (Sachsen in B21 stellen wir wieder auf nein):

Zum Gesamtbeitrag der Pflegeversicherung kommen 0,60% von der fiktiven beitragspflichtigen Einnahme dazu.
646,74 € * 0,60% ergeben 3,88 €. Die Erhöhung schlägt voll beim Arbeitnehmer durch. Der Beitragszuschlag zur Pflegeversicherung wird beim Gesamtbeitrag ermittelt und beim Arbeitnehmer übernommen.
Der Arbeitgeber-Anteil ist immer noch 17,20 €.